Category : Word Processors
Archive   : AMAC43B.ZIP
Filename : MSG001.QM

* msg001.qm
* Macros To Make Index of OffLine Message Reader Messages
* Written By Tom Hogshead
* [ See MSGxx.QM For Use ]
* 5/26/92
* Key Subfile Description
* ===== ============ =================================================
* @2 Make Index of Messages In Saved Message File |chg
* @8 Remove Index of Messages Made with @2
* @4 Make File of Message Headers
*
* {e:\up\MSG??} Return To MSGxx.QM
*
*-- eoi

*  M A C R O S
* --------------------------------------------------------------
* @(2) Make Index of OffLine Mail Reader Messages, v2.15 Only
* --------------------------------------------------------------
* This macro is useful for keeping track of saved messages by making an
* Index of all the messages in an OffLine mail reader saved message
* file and inserting it at the top of the saved message file as shown
* below. After indexing, any message may be easily and quickly viewed
* using AMAC macros in JMPPOSxx.QM (@2-@8) and BOOKxx.QM (@f, @1 or @4).
* Message Index format is as follows:

* Number Date Conf To/From Subject
* (3574) 08-28-91 22 MEL HULSE/DENNIS MCCUNNEY Qedit Menu
* (2498) 04-24-91 22 TOM HOGSHEAD/DENNIS MCCUNNEY OffLine Readers

* NOTE: This macro makes an Index header on line 1 of the saved message
* file if it has not already been made. If an Index header has
* already been made the Index is updated with message header
* details from all messages added since the last Indexing. The
* 'Subject' cannot include the following words each followed by a
* colon: "ber, Date, From, To, Subj, and Conf". The word "ber",
* followed by a colon and a blank space, must not exist anywhere
* in the saved message file since this is the expression used to
* determine if there are any UnIndexed messages. This macro
* encloses the Message Number with ( ) as a bookmark to be
* located and moved to using BOOKxx.QM macros. The ( ) enclosing
* Conference Number are also removed to not conflict with Message
* Number bookmarks as shown below:

* (parenthesis added)
* BBS: SemWare Support BBS v v
* Date: 08-25-91 (00:54) Number:(3562)
* From: MEL HULSE Refer#: 3548
* To: DENNIS MCCUNNEY Recvd: NO
* Subj: Qedit Menu Conf: 22 RelayNet
* ^ ^
* (parenthesis removed)

@2 MacroBegin
SETSCREENOFF
SaveSettings
DefaultWordSet SetInsMode SetSoundOff SetWordWrapMode ToggleWordWrap
Find "ber" ": " Return "G" Return jfalse END * Test if any new msgs
* ------------------ Insert Message Header if None ------------------*
Begfile isEmptyLine jtrue 1 EndLine
Find BackSpace BackSpace Return "B" Return jtrue 2 InsertLine
1: BegLine "*" CursorRight "Number"
GoToColumn "13" Return "Date"
GoToColumn "19" Return "Conf"
GoToColumn "34" Return "To/From"
GoToColumn "56" Return "Subject"
2: * AddLine *|
OneWindow HorizontalWindow EditFile Escape
* ------------------- Locate Next UnIndexed Message -------------------*
PrevFile * Message file window 2
AGAIN:
Find "ber" ": " Return "G" Return jfalse END * End macro if all done
WordRight Backspace MarkWord StoreScrBuff "n" Return * Store msg #
"(" GoToBlockEnd ")" * Bookmark numb as indexed
Find "Date" ":" Return "B" Return * Find Date
CursorUp CursorUp InsertLine
BegLine "*" CursorRight #031 #030 * Insert JMPPOS marker
CursorDown CursorDown CursorDown WordRight UnMarkBlock
MarkCharacter WordRight WordRight WordRight CursorLeft CursorLeft
StoreScrBuff "d" Return * Store Date
Find "From" ":" Return DelLine Return * Find From
WordRight UnmarkBlock DropAnchor CursorRight 25 DropAnchor
StoreScrBuff "f" Return * Store From
CursorUp CursorUp
Find "To" ":" Return DelLine Return * Find To
WordRight UnmarkBlock MarkCharacter CursorRight 25
StoreScrBuff "t" Return * Store To
Find "Subj" ":" Return DelLine Return * Find Subj
WordRight UnmarkBlock MarkCharacter GoToColumn "35" Return
StoreScrBuff "s" Return UnMarkBlock
Find "Conf" ":" Return DelLine Return * Find Conf
MarkCharacter CursorRight 20 MarkCharacter
GoToBlockBeg Find "(" Return "L" Return * Move to '(' if exist
WordRight MarkWord * Mark Conf #
StoreScrBuff "c" Return * Store Conf #
UnMarkBlock Endline
Find "Conf" ":" Return "B" Return * Find Conf
MarkCharacter CursorRight 20 MarkCharacter
* -------- Next lines remove "(" and ")" from Conference # --------*
GoToBlockBeg
FindReplace "(" Return " " Return "LN" Return
FindReplace ")" Return " " Return "LN" Return
UnMarkBlock
PrevWindow * Return to Index
* -------------- Insert Indexed Message Info Into Index --------------*
BegFile AddLine
"*" CursorRight "(" GetScrBuff "n" Return EndLine ")"
GoToColumn "11" Return GetScrBuff "d" Return
EndLine CursorRight GetScrBuff "c" Return
GoToColumn "24" Return GetScrBuff "t" Return
EndLine "/" GetScrBuff "f" Return
GoToColumn "56" Return DelToEol GetScrBuff "s" Return
UnMarkBlock ZoomWindow SetScreenOn SetScreenOff
NextWindow * Window 2
Jump AGAIN
END: ToggleWordWrap BegFile OneWindow RestoreSettings
*
* 461 bytes Fri 09-06-1991 11:17:19 (TH @1, sent to ALL Conf 3, #637)
* 454 bytes Sat 09-07-1991 09:42:04 (TH @2, |a, QEdit v2.15, 3/639, 22/3629)
* 464 bytes Sun 09-08-1991 15:09:20 (TH @2)
* 464 bytes Sun 09-22-1991 00:55:03 (TH @2, for 3 digit Conf #'s)
* 452 bytes Mon 09-30-1991 19:40:19 (TH @2, shortened)
* 449 bytes Fri 10-11-1991 10:38:09 (TH @2, changed To/From)
* 448 bytes Sun 10-27-1991 02:08:45 (TH @2, removed unmarkblock |)
* 450 bytes Wed 11-20-1991 13:08:45 (TH @2, added SaveSettings, sent #3/775)
* 449 bytes Sat 05-16-1992 12:21:46 (TH @2, removed addline *|)

* 
* -------------------------------------------------
* @(4) Makes a File of Message Headers, v2.15 Only
* -------------------------------------------------
* This macro makes a file 'c:\$.hdr' of message headers only, no
* contents. Change 'c:\$.hdr' to your ram drive for faster operation.

@4 MacroBegin
SETSCREENOFF
BegFile UnMarkBlock DropAnchor
EditFile "c:\$.hdr" Return KillFile Quit
WriteBlock Return "O" backspace
StoreScrBuff "header" Return DeleteBlock
LOOP: Find "Date" ":" Return DelLine Return jfalse END
CursorUp CursorUp UnmarkBlock MarkLine CursorDown
Find "Subj" ":" Return DelLine Return
CursorDown MarkLine AppendScrBuff "header" Return jump LOOP
END: GetScrBuff "header" Return WriteBlock Return "O"
DeleteBlock EditFile Return DelLine
*
* 123 bytes Thu 09-05-1991 23:26:09 (TH @4)
* 125 bytes Sun 10-27-1991 01:57:01 (TH @4, changed WriteBlock)

* 
* ----------------------------------------------------------------------
* @(8) UnIndex All Messages in Saved Message File, v2.15 Only
* ----------------------------------------------------------------------
* This macro UnIndexes a saved message file by removing the last Index
* made with @2 from the top of the file, removing the left and right
* parentheses from message number, and deleting the JMPPOS marker. The
* unindexed file is restored to it's original condition with two
* exceptions:
* 1) Parentheses removed from Conference number using @2 are
* not replaced with @8.
* 2) Messages captured from SemWare BBS not using an OffLine
* message reader have the Conference number following the
* Conference name. SLMR messages precede the Conference name
* with number. These BBS captured messages will not be
* re-indexed correctly after UnIndexing with @8 unless the
* Conference name is manually removed before re-indexing with @2.

* SemWare output: -> Conf: RELAYNET (22)
* SLMR output: -> Conf: (22) RelayNet

@8 MacroBegin
SetScreenOff
Begfile EndLine BegLine jfalse FIND * If blank, only add hdr
EndLine Find "ber" Return "B" Return jfalse FIND
unmarkblock markline endpara cursordown deleteblock * Delete last Indx
FIND: Find "ber" ":(" Return DelLine Return jfalse END
UnMarkBlock MarkCharacter EndLine MarkCharacter BegLine
FindReplace
"ber" ":(" Return
"ber" ": " Return "LN" Return * Remove '(' from Number
FindReplace
")" Return
" " Return "LN" Return * Remove '(' from Number
CursorUp CursorUp CursorUp BegLine UnMarkBlock MarkLine MarkLine
Find #31 #30 Return "L" Return jfalse FIND
DelLine * Delete JMPPOS marker
CursorDown CursorDown CursorDown
jump FIND
END: begfile
*
* 123 bytes Sun 09-08-1991 17:57:27 (TH @8)
* 122 bytes Sun 10-27-1991 02:15:24 (TH @8, removed unmarkblock)