Category : Word Processors
Archive   : AMAC43B.ZIP
Filename : DAT002.QM

* dat002.qm
* Written By Tom Hogshead
* [ See DATExx.QM For Use ]
* 5/12/92
* Bytes
* Key Subfile Description/Output Small Fast
* ===== =============== ========================================== ==== ====
* @(f5) Thursday, April 9, 1992 at 11:18 am 137
* @(f6) | 862
* 
* {e:\up\DATE*}--Return To DATExx.QM BEST
*
*-- eoi

*  M A C R O S
* ---------------------------------------------------------------------
* @(f5) Date and Time in English "Thursday, April 9, 1992 at 11:18 am",
* Requires Data Files $date And $time, Small
* ---------------------------------------------------------------------*
* The data files $date and $time must exist in the current directory
* or change "d:\path\" to your path containing these files to
* execute in any directory. Files $date and $time contain:
* ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
* ³$date ³
* ³Mon Monday Tue Tuesday Wed Wednesday Thu Thursday Fri Friday³
* ³Sat Saturday Sun Sunday 01 January 02 February 03 March ³
* ³04 April 05 May 06 June 07 July 08 August ³
* ³09 September 10 October 11 November 12 December ³
* ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
*
* ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
* ³$time ³
* ³01 1 am 02 2 am 03 3 am 04 4 am 05 5 am 06 6 am 07 7 am 08 8 am³
* ³09 9 am 10 10 am 11 11 am 12 12 pm 13 1 pm 14 2 pm 15 3 pm 16 4 pm³
* ³17 5 pm 18 6 pm 19 7 pm 20 8 pm 21 9 pm 22 10 pm 23 11 pm 00 12 am³
* ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ

@f5 macrobegin
* === Insert Date Tuesday, April 14, 1992 at 3:28 pm, From @2 DATE*.QM ===*
setscreenoff setinsmode defaultwordset insertdate
* ------------------------ Remove Second Dash ------------------------*
wordleft toggleinsert backspace wordleft
* ------------------ Remove Day Number Leading Zero ------------------*
unmarkblock markcolumn * Mark day digit 1
findreplace
"0" return delline return "ln" return * Remove leading zero
* ------------------------ Remove First Dash ------------------------*
backspace wordleft wordleft toggleinsert
* ------------------------- Expand Day Name -------------------------*
markword cut onewindow horizontalwindow
editfile
* "d:\path\" * Change to your path for "$date"
"$date" return
find paste return delline return
wordright markword copy prevwindow paste
* ------------------- Insert Comma After Day Name -------------------*
gotoblockend "," delch
* ------------------ Replace Month Number with Name ------------------*
wordright markword cut nextwindow
find paste return delline return
wordright markword copy
quit prevwindow onewindow paste
* ------------------ Insert Comma After Day Number ------------------*
gotoblockend wordright markword gotoblockend "," wordright
markword gotoblockend cursorright * unmarkblock
"at" cursorright
* ========= Insert Time In 3:27 pm Format, From @3 dat002.qm =========*
splitline
inserttime delltword delltword delltword * Delete ":secs "
wordleft wordleft markword cut * Cut 24 hour # to scrap
onewindow horizontalwindow * Setup window for $time
editfile
* "d:\path\" * Change to your path for "$time"
"$time" return
find paste return delline return * Find 24 hour #
wordright markcolumn wordright cursorright * Mark 12 hour and am/pm
copy quit prevwindow onewindow paste * Copy/quit/paste data
wordright markword cursorleft markcolumn * Mark " am/pm"
endline moveblock * Move it where it belongs
endline cursorright joinline unmarkblock * Clean up and pos cursor
*
* 137 bytes Tue 04-14-1992 22:52:27 (TH @f5)
* 137 bytes Tue 05-12-1992 09:16:40 (TH @f5, changed description)

* 
* ---------------------------------------------------------------------
* @(f6) Date and Time in English "Thursday, April 9, 1992 at 11:18 am",
* Revision 1.2 by Mel Hulse
* ---------------------------------------------------------------------*
* This macro is based on the techniques used by Tim Farley and uploaded
* by Patrick Pluto.

@f6 MacroBegin
setscreenoff
UnmarkBlock * Housekeeping
DefaultWordSet * "
InsertDate * Places system date at the cursor position
PrevPosition * Goto front of date string
*------ vvvv If you don't want day spelled out, DELETE FROM HERE ----*
MarkWord * Mark the abreviated day
*------ Replace Day with spelled out name within the marked block----*
FindReplace"Mon" Return "Monday, " Return "LN" Return
FindReplace"Tue" Return "Tuesday, " Return "LN" Return
FindReplace"Wed" Return "Wednesday, " Return "LN" Return
FindReplace"Thu" Return "Thursday, " Return "LN" Return
FindReplace"Fri" Return "Friday, " Return "LN" Return
FindReplace"Sat" Return "Saturday, " Return "LN" Return
FindReplace"Sun" Return "Sunday, " Return "LN" Return
Month: * Target for jump
*--------------------------------------------------------------------*
GotoBlockEnd * Goto the 2 spaces after the day
*------ ^^^^ TO HERE, ----------------------------------------------*
DelRtWord * Delete spaces if Q is configured to...
* delete following white space...
* (Delete day, if your not using it)
UnmarkBlock * Un mark
MarkWord
*------ Replace Month number with Name -----------------------------*
FindReplace"01" Return "January " Return "LN" Return
FindReplace"02" Return "February " Return "LN" Return
FindReplace"03" Return "March " Return "LN" Return
FindReplace"04" Return "April " Return "LN" Return
FindReplace"05" Return "May " Return "LN" Return
FindReplace"06" Return "June " Return "LN" Return
FindReplace"07" Return "July " Return "LN" Return
FindReplace"08" Return "August " Return "LN" Return
FindReplace"09" Return "September " Return "LN" Return
FindReplace"10" Return "October " Return "LN" Return
FindReplace"11" Return "November " Return "LN" Return
FindReplace"12" Return "December " Return "LN" Return
GotoBlockEnd * Go to the space after month
UnmarkBlock * Un mark
Delch * Delete hyphen
*------ Remove Zero in Day Number -----------------------------------*
CursorLeft * Ready for 2 character find...
DropAnchor * Mark 1st...
CursorRight * and second...
DropAnchor * characters
GotoBlockBeg * And go to block's start
FindReplace " 0" Return " " Return "LN" Return * Find a "0" and delete it
GoToBlockEnd * Go toward hyphen
UnmarkBlock * Un mark
CursorRight * And one character more
Delch ", " * Delete hyphen & add comma and space
*--------------------------------------------------------------------*
MarkWord * Mark the year
GotoBlockEnd * Go to the space after the year
UnmarkBlock * Un mark
DelCh * Delete 1 character at years end
*------- Delete after here if time not wanted -----------------------*
* Time: "12:36 pm ", not "12:36:18 "
* -------------------------------------------------------------------*
AltWordSet * Housekeeping - Turn back to DefaultWordSet ....
" at "
InsertTime * Insert the time
Backspace * Backspaces...
Backspace * over...
Backspace * the...
Backspace * seconds
CursorLeft * Go to the end of time
MarkWord * Mark time
GotoBlockBeg * Go to the beginning of time
UnmarkBlock * Un mark
CursorLeft * And 1 character before time
DropAnchor * Mark the...
CursorRight * 1st 2 characters...
DropAnchor * of the hour
CursorLeft * See if it's a "0" and delete it
FindReplace " 0" Return " " Return "ln" Return JTrue am
GoToBlockEnd * Otherwise, convert the hour
UnmarkBlock * Un mark the find block
DropAnchor * Mark...
CursorLeft * the...
DropAnchor * hour
CursorLeft * Go past 1st character
* Look for each 2 digit hour, 11 or less & go to "am"...
FindReplace "10" Return "10" Return "ln" Return JTrue am
FindReplace "11" Return "11" Return "ln" Return JTrue am
* ...or convert it to the 12 hour clock
FindReplace "13" Return "1" Return "ln" Return
FindReplace "14" Return "2" Return "ln" Return
FindReplace "15" Return "3" Return "ln" Return
FindReplace "16" Return "4" Return "ln" Return
FindReplace "17" Return "5" Return "ln" Return
FindReplace "18" Return "6" Return "ln" Return
FindReplace "19" Return "7" Return "ln" Return
FindReplace "20" Return "8" Return "ln" Return
FindReplace "21" Return "9" Return "ln" Return
FindReplace "22" Return "10" Return "ln" Return
FindReplace "23" Return "11" Return "ln" Return
Jump pm * ...and go to "pm"
am: * Target
GotoBlockEnd * Get past time
UnmarkBlock * Un mark the find block
MarkWord GotoBlockEnd UnmarkBlock * Go to the end of time
" am" * Enter "am"
Jump end * Quit
pm: * Target
GotoBlockEnd * Get past time
UnmarkBlock * Un mark the find block
MarkWord GotoBlockEnd UnmarkBlock * Go to the end of time
" pm" * Enter "pm"
end: * Quit target
CursorRight * Put the cursor where user wants it
DefaultWordSet * Put it back where it probably was
*
* 861 bytes, Sunday, April 7, 1991 at 12:41 am
* 861 bytes Thu 04-11-1991 15:59:52 check thh
* 862 bytes Wed 04-08-1992 20:52:32 (TH @f6, added setscreenoff)

* Enjoy!

* ¯ Saturday, April 6, 1991 at 11:39 pm þ .\\œ dzuœse, Silicon Valley ®
* ---
* þ SLMR 1.05 #356 þ Reward for a job well done: more work.

* PCRelay:COMPEASE -> #90 RelayNet (tm)
* 4.10 *Comp-U-Ease* CA. 408-286-8332 HST/V.32/VSM

*--eof