Category : Communication (modem) tools and utilities
Archive   : PRCMSCRP.ZIP
Filename : SNDMAIL.ASP

; aspect script to send genie mail if not logged on do so and then log off
; providing user does not hit escape ( after hitting escape) answer to
; Procomm Question "exit Script Y/N" is irrelevant just hit enter it is
; going to exit the script regardless of the answer.
;
; you must store your user id, password in metakey 9 to use these scripts
; this means there is only one place to change your password
;
; Files to be sent are named XXX.OUT and the receiver is determined by the
; PROC rfindr found near the end of this script it requires changes to your
; specific mailing addresses but works as follows

; file BOB.OUT will be sent to GEmail = MOUNTAIN.MAN
; MIKE.OUT W.Watson9
; you may add as many of these case statements as you like.
;
; After changing this ASP file you must compile it with ASPCOMP for the
; changes to be effective.
;
; this is shareware if you use it please submit a $5.00 regristration fee
; to the author $15.00 for the entire sequence in this package
;
; Stephen Decarie
; 62 Beacham Way NW
; Calgary
; Alberta T3K 1R8
; Canada
;
;
define entry "7" ; change to the Entry for Genie in you Dialing Directory
; define user_id " "
; modified to use metakey for user id, password
; METAKEY 9 must contain USERID/PASSWORD
proc main;
string theday
string teststr ; a string to contain file contents

teststr = $null ; null string
atsay 1 25 46 "GEnie Send Mail" ; say function of script
date theday
fatsay 1 50 46 "Date %s" theday ; puts the date on screen

if CONNECTED

teststr = " No " ; already connected force no reading of mail
goto GNEWS

endif
; not logged on so do so now
locate 0 0 ; locate cursor at 0,0
box 0 0 4 22 14 ; draw box
atsay 2 2 14 "Logging onto GENIE." ; put message in box
locate 6 0 ; cursor to row 6
pause 1 ;
dial entry ; if directory changes this does too!
transmit "HHH" ;
waitfor "#=" 30 ;
set duplex full ;
; transmit USER_ID ;
metakey 9 ; define metakey 9 to be userid, password
transmit "^M" ; followed by a carriage return
set duplex half ; restore screen display

waitfor "Last" forever ; defines when to open temporary log
delete "log.tmp" ; delete previous mail check log if any
log open "log.tmp" ; open log file for the mail message
waitfor "Enter" forever ; keys on next line after Number letters
log close ; close this log
fopen 0 "log.tmp" "rt" ; open this log to read it as text
integer len ;
fread 0 teststr 80 len ; read the file

fclose 0 ; close this log file
waitfor "continue?" 120;
pause 1;
transmit " ^M" ; a carriage return
waitfor "?" ;

box 1 30 3 58 79 ; display logon time
fatsay 2 32 41 " logged on at %s " $time0

pause 5;

GNEWS: ; mail operation starts here
transmit "*gemail" ;
transmit " ^M" ; a carriage return

string spec = "*.out"
integer another = 0;
clear ;
findfirst spec ; find first file
if found ;
another = 1 ;
fatsay 1 1 7 " file to send %s" $filename
endif ;

waitfor "P 8004?" 20;
string recevr
string filen
while another
filen = $filename
call rfindr with filen &recevr

transmit "7" ; send mail (via upload)
transmit " ^M" ; a carriage return
waitfor "to send your mail" 120
waitfor "To:" forever
clear

transmit recevr ;
transmit " ^M" ; a carriage return
waitfor "Carbon Copy:" 30
transmit " ^M" ; a carriage return
waitfor "Sub:" 30
transmit " ^M" ; a carriage return
waitquiet 30 ;


sendfile ascii $filename ;
waitquiet 30;
transmit "^[" ; send escape
waitfor ">" 40
transmit "*s";

transmit " ^M" ; a carriage return
pause 1

delete $filename

waitfor "P 8004?" forever ;

findnext

if found
fatsay 2 2 7 "%s" $filename
else
exitwhile
endif

endwhile

find teststr "No" ; if the string contains "No" then no mail

if not found ; there is mail to be read
string file = "mail.txt" ;
delete file ;
if failure
fatsay 0 0 31 "Can't delete %s" file
endif ;
log open file ;
pause 1;
transmit "rea" ;
transmit " ^M" ; a carriage return
waitfor "P 8004?" forever ;
log close ;
endif

execute "GENSTART.ASX" ; go back to menu

endproc

proc rfindr
strparm filen
strparm recevr
switch filen

case "BOB.OUT"
recevr = "MOUNTAIN.MAN"
endcase

case "MIKE.OUT"
recevr = "W.WATSON9"
endcase

case "ED.OUT"
recevr = "E.CHILTON"
endcase

CASE "ALAN.OUT"
recevr = "A.SCHULTZ3"
endcase

CASE "JOEY.OUT"
recevr = "J.GASPE1"
endcase
CASE "susan.out"
recevr = "s.brennan2"
endcase

CASE "merle.oUT"
recevr = "M.smith24"
endcase

CASE "moose.OUT"
recevr = "mister-moose"
endcase
CASE "Joke.out"
recevr = "JOKEMASTER"
endcase
endswitch
endproc