Category : Communication (modem) tools and utilities
Archive   : PRCMSCRP.ZIP
Filename : GENIEFAX.ASP

; aspect script to send a genie FAX from a file
; Script logs on assuming USerid, password is in MetaKEy 9
; Sends the fax then logs back off.
; you must store your user id, password in metakey 9 to use these scripts
; this means there is only one place to change your password
;
; this is shareware if you use it please submit a $5.00 regristration fee
; to the author $15.00 for the entire sequence in this package
;
; Stephen Decarie
; 62 Beacham Way NW
; Calgary
; Alberta T3K 1R8
; Canada
; Stephen Decarie 11 - 03 -92
; Gemail = S.Decarie

; define user_id " , "
define entry "7"
proc main;
string contry,area,phone,country
string individ,subject
string filenm
integer varlen
country = "1"
contry = $null
area = $null
phone = $null
filenm = $null

clear
box 3 15 14 79 41
atsay 4 26 41 "GEnie Fax Send"
atsay 6 21 41 "Enter Fax Information:"
atsay 8 18 41 "1. Country ( 1 for US & Canada):"
atsay 9 18 41 "2. Area Code 3 digits :"
atsay 10 18 41 "3. phone number XXX-XXXX :"
atsay 11 18 41 "4. File name :"
atsay 12 18 41 "5. Individual to address :"
atsay 13 18 41 "6. Subject :"

fatsay 8 51 41 "%s" country
atget 8 50 41 1 contry
atget 9 50 41 3 area
atget 10 50 41 8 phone
atget 11 50 41 12 filenm
atget 12 50 41 21 individ
atget 13 50 41 28 subject

strlen contry varlen

if varlen < 1
contry = "1"
endif

clear ; clear screen
locate 0 0 ; locate cursor at 0,0
box 0 0 4 22 14 ; draw box
atsay 2 2 14 "Logging onto GENIE." ; put message in box
locate 6 0 ; cursor to row 6
pause 1 ;
dial entry ; if directory changes this does too!
transmit "HHH" ;
waitfor "#=" 30 ;
set duplex full ;

;transmit USER_ID ;
metakey 9 ; user id , password stored in meta key 9

transmit "^M" ; followed by a carriage return
set duplex half ; restore screen display
waitfor "continue?" 120;
pause 1;
transmit " ^M" ; a carriage return
waitfor "?" ;

box 1 30 3 58 79 ; display logon time
fatsay 2 32 41 " logged on at %s " $time0

pause 5;
transmit "fax" ;
transmit " ^M" ; a carriage return
waitfor "205?" forever
transmit "6"
transmit " ^M" ; a carriage return
waitfor "code?" forever
transmit contry
transmit " ^M" ; a carriage return
waitfor "machine?" forever
transmit area
transmit " ^M" ; a carriage return
waitfor "machine?" forever
transmit phone
transmit " ^M" ; a carriage return

waitfor "?" forever
transmit individ
transmit " ^M" ; a carriage return

waitfor "?" forever
transmit "N" ; addditional fax machine
transmit " ^M" ; a carriage return

waitfor "?" forever
transmit "Y" ; receive a copy in your own mail box
transmit " ^M" ; a carriage return

waitfor "?" forever
transmit subject ;
transmit " ^M" ; a carriage return

waitquiet 20
transmit "*up" ;
transmit " ^M" ; a carriage return

waitquiet 20
sendfile ascii filenm
waitquiet 20;
transmit "^[" ; send escape
waitfor ">" 40
transmit "*s";

transmit " ^M" ; a carriage return
pause 1

waitfor "FAX?" 30
transmit "N";
transmit " ^M" ; a carriage return

waitfor "?" 30
atsay 10 5 46 "HIT ESCAPE TO STAY LOGGED ON"
pause 5
if success
execute "lofgenie.asx" ; log of genie
else
execute "GENSTART.ASX" ; go back to menu
endif
exit
;
endproc