Category : Communication (modem) tools and utilities
Archive   : PRCMSCRP.ZIP
Filename : FILESEND.ASP

; aspect script to send a file via genie Mail. File is uploaded with Xmodem.
;
; you must store your user id, password in metakey 9 to use these scripts
; this means there is only one place to change your password
;
; After changing this ASP file you must compile it with ASPCOMP for the
; changes to be effective.
;
; this is shareware if you use it please submit a $5.00 regristration fee
; to the author $15.00 for the entire sequence in this package
;
; Stephen Decarie
; 62 Beacham Way NW
; Calgary
; Alberta T3K 1R8
; Canada
;
;
define entry "7" ; change to the Entry for Genie in you Dialing Directory
; define user_id " "
; modified to use metakey for user id, password
; METAKEY 9 must contain USERID/PASSWORD
proc main;
string theday
string receivef,address,filnm ,descript,subj
atsay 1 25 46 "GEnie Send File" ; say function of script
date theday
fatsay 1 50 46 "Date %s" theday ; puts the date on screen

box 3 14 17 75 41
atsay 4 18 41 "ÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ"
atsay 5 18 41 "ºGEnie mail File Sendº"
atsay 6 18 41 "º º"
atsay 7 18 41 "ºFile name to send : º"
atsay 8 18 41 "ºReceiver file name: º"
atsay 9 18 41 "ºDescription : º"
atsay 10 18 41 "ºSubject : º"
atsay 11 18 41 "ºGemail address : º"
atsay 12 18 41 "ÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ"

atget 7 41 44 12 filnm
atget 8 41 44 12 receivef
atget 9 41 44 30 descript
atget 10 41 44 12 subj
atget 11 41 44 15 address


clear ; clear screen
if CONNECTED

goto sendit

endif
; not logged on so do so now
locate 0 0 ; locate cursor at 0,0
box 0 0 4 22 14 ; draw box
atsay 2 2 14 "Logging onto GENIE." ; put message in box
locate 6 0 ; cursor to row 6
pause 1 ;
dial entry ; if directory changes this does too!
transmit "HHH" ;
waitfor "#=" 30 ;
set duplex full ;
; transmit USER_ID ;
metakey 9 ; define metakey 9 to be userid, password
transmit "^M" ; followed by a carriage return
set duplex half ; restore screen display

waitfor "continue?" 120;
pause 1;
transmit " ^M" ; a carriage return
waitfor "?" ;

box 1 30 3 58 79 ; display logon time
fatsay 2 32 41 " logged on at %s " $time0

pause 5;

Sendit: ; mail operation starts here
transmit "200" ;
transmit " ^M" ; a carriage return
waitfor "?" 40
transmit "11" ; select file option
transmit " ^M" ; a carriage return
waitfor "?" 40
transmit receivef ; receiver file name
transmit " ^M" ; a carriage return
waitfor "t?" 40
transmit "1" ; selects XMODEM protocol
transmit " ^M" ; a carriage return
waitquiet 30
sendfile XMODEM filnm

waitfor ">?" 45
transmit "^M" ; return
waitfor "prompt."
transmit "^M" ; return

waitfor "To:" 45
transmit address
transmit " ^M" ; a carriage return
waitfor ":" 45 ; carbon copy
transmit " ^M" ; a carriage return
waitfor "1>" 30
transmit descript ; description
transmit " ^M" ; a carriage return
waitfor "2>" 30
transmit "*s" ; send it
transmit " ^M" ; a carriage return
waitquiet 30
execute "GENSTART.ASX" ; back to mail menu
endproc