Category : Communication (modem) tools and utilities
Archive   : PRCMSCRP.ZIP
Filename : DLDIBM.ASP

; script to Down load a file from the IBM PC library using ZMODEM
; as it is the fastest protocol available.
;
; You must store your user id, password in metakey 9 to use these scripts
; this means there is only one place to change your password
;
; If your hourly RATE is not $6.00 per hour change this variable (line 29)
;
;
; this is shareware if you use it please submit a $5.00 regristration fee
; to the author $15.00 for the entire sequence in this package
; Stephen Decarie
; 62 Beacham Way NW
; Calgary
; Alberta T3K 1R8
; Canada
;
;
define entry "7" ; dialing directory entry for Genie change to your number
string stime;
string etime ; start & end times

proc main

string chrs,cmins,csecs ;
string chre,cmine,csece ; character version of of hours & minutes
string filenum ; number of the file to download
float RATE = 8.56 ; Genie charge rate per hour

float COST , elapsed
float hrs,mins,secs;
float hre,mine,sece ;
float hr,min,sec ;

when 0 "aborted" transmit "ATH0^M" ; should hang up

integer logstat =0 ; 0 means not currently on;
string theday

clear ; clear screen
atsay 1 25 46 "GEnie IBM file Down Load"
date theday
fatsay 1 55 46 "Date %s" theday
fatsay 10 30 46 "Enter Number of file to be Downloaded "
atget 10 67 46 6 filenum

if CONNECTED
logstat = 1 ; currently logged on
goto MIBM
endif
; not logged on so do so now
locate 0 0 ; locate cursor at 0,0
box 0 0 4 22 14 ; draw box
atsay 2 2 14 "Logging onto GENIE." ; put message in box
locate 6 0 ; cursor to row 6
pause 1 ;
dial entry
transmit "HHH" ;
waitfor "#=" 30 ;
set duplex full ; ensure password & userid not visible

metakey 9; transmit user id/password stored in metakey 9
transmit "^M" ; followed by a carriage return
set duplex half ; restore screen display
waitfor "continue?" 30 ;
pause 1;
transmit " ^M" ; a carriage return
waitfor "?" ;

MIBM:
call timestr ; start clock
transmit "M615" ; moves to page 615 is PC round table, 3 = library
transmit "^M" ; carriage return

waitfor "?" ;
transmit "3" ; moves to the library
transmit "^M" ; carriage return

waitfor "?" ;
transmit "6" ; select download option
transmit "^M" ; carriage return

waitfor "?" ;
transmit filenum ; file number to download
transmit "^M" ; carriage return

waitfor "?" ;
transmit "D" ; download it
transmit "^M" ; carriage return

waitfor "?" ;
transmit "4" ; select Zmodem protocol
transmit "^M" ; carriage return

waitfor "?" forever ;
transmit "N" ; no more
transmit "^M" ; carriage return

waitfor "?" ;
transmit "top" ; back to basic service
transmit "^M" ; carriage return

call etimend ; stop clock
substr csecs stime 6 2 ; extract seconds, minutes & hours
substr cmins stime 3 2 ; of both start and end time
substr chrs stime 0 2

substr csece etime 6 2 ; end time
substr cmine etime 3 2
substr chre etime 0 2

atof csecs secs ; convert character data to float
atof chrs hrs
atof cmins mins

atof chre hre ; end times to float
atof cmine mine
atof csece sece

hr = hre - hrs; # hours
min = mine - mins; # minutes
sec = sece - secs ; # seconds

if( sec < 0 ) ; more than 1 minute
sec = sec + 60
min = min - 1
endif

if ( min < 0 ) ; hourly boundary
min = min + 60
if hr > 0
hr = hr - 1
endif
endif

if (hr < 0) ; note we are using Military time
hr = hr + 24 ; this should only happen at midnight (untested)
endif


elapsed = hr + min/60 + sec / 3600; elapsed time in hours
cost = RATE * elapsed;
box 11 30 13 50 76 ; display cost
fatsay 12 33 41 " cost %f " cost ; cost of retrieval
pause 10 ;
execute "GENSTART.ASX"
endproc
proc timestr
box 1 32 3 50 79 ; display leaving time
time stime 1
fatsay 2 34 41 " time %s " stime
pause 10 ;
endproc
proc etimend
box 7 30 9 50 78 ; display leaving time
time etime 1
fatsay 8 32 41 " time %s " etime
pause 10 ;
return
endproc