Category : Word Processors
Archive   : FMACS16A.ZIP
Filename : ASM.MIN

[*]#(ds,Fext-mode-list,##(Fext-mode-list)(.asm,ASM,
))
#(ds,Fmodified)
#(F:save-all-libs)
[*]


Support for assembly language. Press C-c C-c to install, then answer 'y'
to write the changes to disk.



Name:U:asm-format
Reformat assembly language into a consistent indentation format.
[*]#(sp,^)
#(Fwhitespace,(
#(F:delete-horizontal-whitespace)
#(==,##(rc,$),0,,(
#(sp,^<^)
#(Fforward-skip-white,no)
#(ds,temp,#(Fcase,##(bc,##(rm,>)),
(##(bc,;),(( ))),
(13,(( ))),
(##(rm,^))
))
#(sp,$)
#(==,##(rm,<),:,(#(ds,temp,( ))))
#(sp,$>)
#(is,#(==,##(temp),,( ),(##(temp))))
))
),,nocrlf)
#(Uasm-format-do)
#(sp,$>)[*]


Name:F:asm-mode
[*]#(F:ASM-mode)[*]


Name:Uasm-format-do
[*]#(Fcase,##(bc,##(rm,>)),
(##(bc,"),),
(##(bc,'),),
(##(bc,;),),
(13,),
(
#(Fwhile-yes,(
#(Fwhitespace,,(
#(sp,>)
yes
))
))
#(==,##(rc,$),0,,(
#(F:delete-horizontal-whitespace)
#(==,##(rm,<),(,),,(
#(is,( ))
))
#(SELF)
))
)
)[*]


Name:U:masm
[*]#(ds,masm-buffer,#(Fbuffer-fn))
#(F:write-modified-files)
#(Ffind-or-make-buffer,*masm*)
#(ex,#(Fsearch-path,masm),#(masm-buffer);,,\pipe_out,\pipe_out)
#(rf,\pipe_out)
#(de,\pipe_out)
#(ds,error-buffer,##(ba,-1))
#(es,error-handler)
#(ds,k,##(gs,Fredisplay-two))
#(sv,ow,##(ba,-1))
#(sp,[)
#(..,##(ba,##(old-buffer)))
#(Fenter-local-modes)
[*]


Name:U:ASM-colon
Insert a colon, and delete the indentation iff it follows a label.
[*]#(Fsave-excursion,(
#(sp,^)
#(Flooking-at,([ ##(bc,9,d,a)][ ##(bc,9,d,a)]*[a-zA-Z_][a-zA-Z_]*$),(
#(Ffind-non-blank,>,arg1)
#(dm,^)
))
))
#(is,:)[*]


Name:U:ASM-comment
Introduce a comment or convert an already existing comment into a
comment of a `bigger' kind. These are the known comment classes:

1-- to the right of the code (at the comment-column)
2-- comment on a own line, indented like code
3-- at the left-most column.

Suggested usage: while writing your code, trigger asm-comment
repeatedly until you are satisfied with the kind of comment.
[*]#(Fand,(#(==,##(lv,cs),##(F-comment-column))),(#(==,##(rc,$),0)),(
#(is,##(F-left-comment))
),(
#(sp,^)
#(Flooking-at,.*#(Fregexp-quote,(##(F-left-comment))),(
#(sp,$)
#(pm,1)
#(lp,##(F-left-comment))
#(l?,.,^,0,,(#(sp,0)))
#(pm)
#(F:delete-horizontal-whitespace)
#(==,##(rc,^),0,(
#(sp,$)
),(
#(Fcrlf)
#(Fpad-to-column,##(F-comment-column))
))
),(
#(F:indent-for-comment)
))
))
[*]


Name:F:ASM-mode
This will set the local mode to Assembly Language.
[*]#(Fexit-mode)
#(Flocal-bind-key,F-left-comment,;)
#(Flocal-bind-key,F-right-comment,)
#(Flocal-bind-key,K.M-C-i,U:asm-format)
#(Flocal-bind-key,K.M-Tab,U:asm-format)
#(Flocal-bind-key,staydown-hook,(
#(n?,UASM-staydown-do.ARG1,(
#(UASM-staydown-do.ARG1)
),(
#(Fstaydown-do-do,ARG1)
))
))
#(mp,staydown-hook,,ARG1)
#(Fset-modename,ASM)
[*]


Name:UASM-staydown-do.59
[*]#(Fbackward-skip-white)
#(Fstaydown-mark,$)[*]