Category : Databases and related files
Archive   : PBASE.ZIP
Filename : MAILLIST.PRG

* MAILLIST.PRG (10-03.a)

SWITCH TALK OFF
RESET DATABASE
RESET FORM
DROP VARIABLE ALL

FORM TEXT 'First-Initial-Last:' AT 3 3
FORM TEXT 'Mr/s:' AT 3 53
FORM TEXT 'Title:' AT 5 16
FORM TEXT 'Company:' AT 6 14
FORM TEXT 'Address Line 1:' AT 8 7
FORM TEXT 'Address Line 2:' AT 9 7
FORM TEXT 'City-State-Zip:' AT 10 7
FORM TEXT 'Phone:' AT 12 16
FORM TEXT 'Date:' AT 12 38
FORM TEXT 'User 1:' AT 14 15
FORM TEXT 'User 2:' AT 15 15
FORM FIELD mlname1 PICTURE 'A^^^^^^^^^^' AT 3 23
FORM FIELD mlname2 PICTURE 'A.>' AT 3 35
FORM FIELD mlname3 PICTURE 'A^^^^^^^^^^^^^' AT 3 38
FORM FIELD mlmrms WIDTH 5 AT 3 59
FORM FIELD mltitle WIDTH 30 AT 5 23
FORM FIELD mlcomp WIDTH 30 AT 6 23
FORM FIELD mladdr1 WIDTH 30 AT 8 23
FORM FIELD mladdr2 WIDTH 30 AT 9 23
FORM FIELD mlcity WIDTH 15 AT 10 23
FORM FIELD mlstate PICTURE 'AA>' AT 10 39
FORM FIELD mlzip WIDTH 10 AT 10 42
FORM FIELD mlphone PICTURE '(###)###-####>' AT 12 23
FORM FIELD mldate PICTURE '##/##/##>' AT 12 44
FORM FIELD mluser1 WIDTH 15 AT 14 23
FORM FIELD mluser2 WIDTH 15 AT 15 23

DOWHILE true
CLEAR SCREEN
DOMENU
MENUTITLE '[ Mailing List Main Menu ]'
MENUOPTION 'Edit Records'
MENUOPTION 'Print Mailing Labels'
MENUOPTION 'Print Reports'
MENUOPTION 'Initialize Data Base'
MENUOPTION 'Backup "PUBS" table'
MENUOPTION 'Quit'
MENUCHOICE choice
ENDMENU
********** **********
DOCASE
CASE choice=1
CREATE CURSOR 1 FOR mail
USE CURSOR 1
editform pubs
DROP CURSOR 1
********** **********
CASE choice=2
CREATE CURSOR 1 FOR mail
USE CURSOR 1
SET PRINT TO PRINTER
SELECT mlname1,mlname3,mlmrms,mltitle,mlcomp,mladdr1,mladdr2,;
mlcity,mlstate,mlzip FROM pubs
TEMPLATE PRINT TOLBL
SELECT mluser1 FROM pubs
TEMPLATE PRINT FROMLBL
SELECT mlname1,mlname3,mlcomp,mluser1 FROM pubs
TEMPLATE PRINT FLOPLBL
DROP CURSOR 1
********** **********
CASE choice=3
RESET REPORT
DOMENU
MENUTITLE '[ Report ORDER Specification ]'
MENUOPTION 'By NAME'
MENUOPTION 'BY ZIPCODE'
MENUOPTION 'By COMPANY'
MENUOPTION 'Return to Main Menu'
MENUCHOICE choice
ENDMENU
DOCASE
CASE choice=1
ASSIGN 'mlname3,mlname1,mlname2,mlzip' TO mlorder
CASE choice=2
ASSIGN 'mlzip,mlname3,mlname1,mlname2' TO mlorder
CASE choice=3
ASSIGN 'mlcomp,mlname3,mlname1,mlname2' TO mlorder
CASE choice=4
LOOP
ENDCASE
CREATE CURSOR 1 FOR mail
USE CURSOR 1
SELECT mlname1,mlname2,mlname3,mlmrms,mltitle,mlcomp,mladdr1,mladdr2,;
mlcity,mlstate,mlzip,mlphone,mldate,mluser1,mluser2 FROM pubs;
ORDER BY &mlorder
DOREPORT
REPORT OUTPUT
TO PRINTER
END
REPORT PAGE HEADING
PRINT SYSDATE SYSTIME TAB 25 'List of Contacts' TAB 50 'Page ' SYSPAGE SKIP 2
END
REPORT PAGE DETAIL
PRINT TAB 5 mlname3 ', ' mlname1 ' 'mlname2 TAB 40 mladdr1 SKIP
PRINT TAB 5 mltitle TAB 40 mladdr2 SKIP
PRINT TAB 5 mlcomp TAB 40 mlcity TAB 50 mlstate ' ' mlzip SKIP
PRINT TAB 5 mlphone PICTURE '(^^^)^^^-^^^^' TAB 20 mldate PICTURE '^^/^^/^^' SKIP
PRINT TAB 5 mluser1 TAB 25 mluser2 SKIP 2
END
ENDREPORT
DROP VARIABLE LIKE 'ml??????'
DROP CURSOR 1
********** **********
CASE choice=4
IF ISYES('[ Are you sure? ]')
SHOW MESSAGE 'Creating data base "MAIL"'
CREATE DATABASE mail
SHOW MESSAGE 'Creating table "PUBS"'
CREATE CURSOR 1 FOR mail
USE CURSOR 1
CREATE TABLE pubs (mlname1 char(11),mlname2 char(1),mlname3 char(14),;
mlmrms char(5),mltitle char(30),mlcomp char(30),mladdr1 char(30),;
mladdr2 char(30),mlcity char(15),mlstate char(2),mlzip char(10),;
mlphone char(11),mldate char(6),mluser1 char(15),mluser2 char(15))
DROP CURSOR 1
ENDIF
********** **********
CASE choice=5
CREATE CURSOR 1 FOR mail
USE CURSOR 1
SELECT mlname1,mlname2,mlname3,mlmrms,mltitle,mlcomp,mladdr1,mladdr2,;
mlcity,mlstate,mlzip,mlphone,mldate,mluser1,mluser2 FROM pubs
EXPORT TO temp
DROP CURSOR 1
********** **********
CASE choice=6
DROP VARIABLE LIKE 'ml??????'
RETURN
ENDCASE
ENDWHILE