Category : Miscellaneous Language Source Code
Archive   : FINISH24.ZIP
Filename : INSTALL.FIL

 
Output of file : INSTALL.FIL contained in archive : FINISH24.ZIP
' Sample Install Script for
' The Finishing Touch
' Professional Software Installer
' Copyright 1993, ImagiSOFT, Inc.
' April 1, 1993

' NOTE: This script file takes a LONG TIME to load because INSTALL.EXE
' does a CRC check of the documentation files before proceeding.
' The registered version does NOT do this.

' There is a 400 line maximum for any one script file. However,
' this limitation can be overcome by using the SCRIPT command.

' This script file doesn't use all the possible commands.
' See the documentation for the commands to check hardware,
' perform conditional jumps, view ASCII files, run or shell
' to DOS programs, change AUTOEXEC.BAT and CONFIG.SYS,
' invoke other script files, and more!

BACKGROUND 63 ' display cyan colored background (see color chart in docs)

LANGUAGE ENGLISH
' French, German, and Spanish are also supported. English is the default

BORDER 1 ' single line borders. 2 = double, 0 = no border

TELESCOPE OFF ' turn off "exploding" or telescoping windows
' this will make the window instantly appear


WINOPEN 18 2 95 ' display the heading in a window
' located at 18 characters across
' 2 rows down with a
' magenta background and high intensity white letters
' (see color chart)

" ImagiSOFT, Inc."
"Where Imagination Brings Software to Life "
""
""
""
""
""

' WINOPEN 0 2 95 ' use this command instead to make sure the
' window is centered horizontally on the screen

' another nice feature is the ability to write text in a different color
' within a window. Most commands can use relative cursor positions, as
' shown in this example:
PAUSE 100
WINUPDATE +13 +4 94
"THE FINISHING TOUCH" ' yellow text
' 13 characters across
' and 4 rows down
' from the upper left hand corner of the window
PAUSE 50 ' 1/2 second delay between words
WINUPDATE +2 +5 95
"Professional Software Installation Program"
PAUSE 50
WINUPDATE +17 +6 95
"Version 2.4"
PAUSE 50
WINUPDATE +16 +7 95
"April 1, 1993"
PAUSE 300 ' 3 second delay

TELESCOPE ON ' turn on telescoping windows for the rest of the messages

SHADOW ON
' display all messages from this point on in a "shadowed" window
' the default is "OFF". This feature can be turned on and off as many
' times as you want

WINOPEN 0 12 31
"THE FINISHING TOUCH WILL SAVE YOU MONEY BY . . . "
""
""
""
""
""
""
""
WINUPDATE +36 +1 26
"MONEY"
PAUSE 300 ' 3 seconds
WINUPDATE +2 +3 30
"þ Cutting the number of disks in your program in half."
" (see the UNPACK command and PACKER utility)"
BEEP
PAUSE 200
WINUPDATE +2 +3 31
"þ Cutting the number of disks in your program in half."
" (see the UNPACK command and PACKER utility)"
WINUPDATE +2 +6 30
"þ Reducing your installation support problems."
BEEP
PAUSE 200
WINUPDATE +2 +6 31
"þ Reducing your installation support problems."
WINUPDATE +2 +8 30
"Press the [Enter] key to continue."
WAIT +36 +8 ' wait for the enter key
WINCLOSE ' close the window

BORDER 2 ' double line border
' window = blue with green border
WINOPEN 0 12 18
" " ' widest message determines
"" ' the width of the window
"" ' this window is nine lines
"" ' long.
""
""
""
""

' white letters inside window
WINUPDATE +2 +2 31
"þ Is Rich with Powerful Features"
""
"þ Is Easy to Learn"
" (Look at INSTALL.FIL for this script)"
""
"þ Can be as simple or complex as you want"

' heading = yellow text on green
WINUPDATE +14 +0 46 ' +0 = top border
" THE FINISHING TOUCH "

' bottom of window green / blue letters
WINUPDATE +16 +9 33 ' +9 = bottom border
" Press [Enter] " ' (good when space is tight)
WAIT +30 +9 ' wait for enter key, cursor location
WINCLOSE ' close window

BORDER 1 ' personally, I like single borders
WINOPEN 0 12 31
"This sample installation file will demonstrate some of"
"THE FINISHING TOUCH'S features by installing a FREE"
"file date and time stamping utility."
""

WINUPDATE +49 +2 27 ' change the color of
"FREE" ' the word "free" to cyan

WINUPDATE +15 +5 31 ' write on top of bottom border
" Press [Enter] to continue " ' (good when space is tight)

WINUPDATE +22 +5 30 ' yellow text
"[Enter]"

WAIT +41 +5 ' wait for the enter key
WINCLOSE ' close the window

' Tell INSTALL the minimum amount of required disk space
SPACE 7 ' This sample is tiny, only 7K required.

' Prompt for the drive to install to:
DRIVE C 0 12 31 15 32 14 79
' C = drive C, the pre-stuffed drive letter
' 0 = center window horizontally
' 12 = and 12 rows down
' 31 = blue background and high intensity white foreground
' 15 = input on a black background w/ high intensity white letters
' 32 = error message located at 32 characters across
' 14 = and 14 rows down
' 79 = any error message will appear in a red window with
' high intensity white letters

' After the user selects a drive and presses [Enter], the first thing
' the DRIVE command does is make sure the drive exists. Next it will
' check for the required disk space. If the drive does not exist, or
' there is not enough space, an error message appears, and the user is
' required to pick a different drive, or quit.

' Prompt with default path \SAMPLE
' INSTALL.EXE will work the same way whether the user enters SAMPLE,
' \SAMPLE\, or \SAMPLE. Mutiple directories such as \SAMPLE\UTIL\FREE
' are also supported.
PATH \SAMPLE 0 12 31 15 32 14 79

' the numbers above represent window locations and colors. See the
' documentation for more details

' Unpack the files from the floppy drive.

UNPACK SAMPLE.PAK 0 12 31 32 14 79
' SAMPLE.PAK was compressed using the enclosed PACKER utility. This
' utility will compress files 50% or more depending on the file type.
' you should get compression results close to that of PKZIP.
' the numbers above represent window locations and colors. See the
' documentation for more details

' just for fun, open the disk drive right in the middle of the installation
' and see what happens. This is only one of four "jump" commands supported.
' see the documentation for JUMP, JUMP.NO, and JUMP.YES commands.

JUMP.FAIL INSTALL_FAILURE

WINOPEN 0 12 31

"A FREE file stamping utility has been installed on your"
"computer in the directory"
""
"This is our way of saying THANKS for taking the time to"
"review the THE FINISHING TOUCH!"
""
"Press the [Enter] key to continue."

WINUPDATE +28 +2 30 ' display text in yellow
"~1~2."

WINUPDATE +28 +4 27 ' cyan
"THANKS"

WAIT +36 +7
' Wait for the user to press the [Enter] key so they can
' read the above window.
' The plus signs denote that you want the cursor located relative to
' the upper left hand corner of the window (position 0, 0) 7 rows down
' and 36 characters across.

WINCLOSE ' close the above window

' ------------------------------------------------------
' Ask user if they would like to view the utility's docs
' ------------------------------------------------------
WINOPEN 0 12 31
"Would you like to see the new utility's documentation?"
"" ' this is necessary so that the winupdate
' command will have some place to display the
' (Y or N)

WINUPDATE +25 +2 30 ' yellow text
"(Y or N)"

ASK +33 +2 ' one method of providing a "conditional" jump
' note relative cursor positioning

WINCLOSE ' close the above window

JUMP.NO VIEW_INSTALL.TXT ' skip the view command if the user
' hits the "N" key from the above
' ASK statement.

VIEW ~1~2\STAMP.TXT 79 31 ' as you can see, The Finishing Touch
' has a built-in file viewer

' -----------------------------------------------------
' Ask user if they would like to view the documentation
' -----------------------------------------------------
:VIEW_INSTALL.TXT
WINOPEN 0 12 31
"Would you like to SEE the documentation for THE FINISHING TOUCH?"
""

WINUPDATE +31 +2 30 ' yellow text
"(Y or N)"

ASK +39 +2 ' one method of providing a "conditional" jump
' again, relative cursors are easier

WINCLOSE ' close the above window

JUMP.NO PRINT_INSTALL.TXT ' again, skip the view command if the user
' hits the "N" key from the above ASK statement.

WINOPEN 0 0 31 ' large file takes a while from floppy ...
"Loading 67 Pages ..."
VIEW ~0\INSTALL.TXT 79 31
WINCLOSE ' close the above window

' -------------------------------------------------------
' Ask user if they would like to print the documentation
' -------------------------------------------------------
:PRINT_INSTALL.TXT
WINOPEN 0 12 31
"Would you like to PRINT the documentation for THE FINISHING TOUCH?"
""

WINUPDATE +31 +2 30 ' yellow text
"(Y or N)"

ASK +39 +2 ' one method of providing a "conditional" jump

WINCLOSE ' close the above window
JUMP.NO EXIT

WINOPEN 0 0 31 ' printing large file takes a while ...
""
" Printing 67 Pages ... "
""
PRINT ~0\INSTALL.TXT
WINCLOSE ' close the above window
JUMP.FAIL PRINTER_ERROR ' jump on fatal error
JUMP EXIT ' print successful, skip next

:PRINTER_ERROR ' label for error condition
WINOPEN 0 12 79 ' open the following window
"Your printer is not responding. Possible problems:"
" -- Printer is not turned on"
" -- Printer is out of paper"
" -- Printer is not attached to LPT1 (parallel port 1)"
""
"Do you want to try to print again (Y or N)?"
ASK 57 18 ' prompt for Y or N key (fixed cursor position)
WINCLOSE ' close this window
JUMP.YES PRINT_INSTALL.TXT ' y key pressed, print

' ----------------------
' display closing window
' ----------------------
:EXIT

WINOPEN 0 12 31 ' window is centered on screen
"Thank you for running the installation demonstration for the"
""
" THE FINISHING TOUCH"
" The Professional Installation Program"
""
"You have a fully working shareware evaluation copy. We hope"
"that you will find THE FINISHING TOUCH is the most powerful,"
"smallest, easiest to use, software installer with the best"
"file compression available anywhere. ENJOY!"
""

WINUPDATE +21 +3 30
"THE FINISHING TOUCH" ' yellow text
WINUPDATE +40 +9 27
"ENJOY!" ' cyan text
WINUPDATE +12 +11 31 ' write on top of bottom border
"´ Press the [Enter] key to continue Ã" ' (good when space is tight)
WINUPDATE +24 +11 30
"[Enter]"
WAIT +47 +11
WINCLOSE

' display our bbs phone number
BORDER 2 ' double line borders supported
' for no border, use BORDER 0
WINOPEN 0 12 110
"If you're not sure you have the latest shareware copy of"
"THE FINISHING TOUCH, call the Software Creations BBS:"
""
""
""
""
""
""
""
"Press the [Enter] key to continue."

WINUPDATE +28 +2 107
"Software Creations BBS"
WINUPDATE +13 +4 106
"33 Lines to Serve You 24 Hours per Day!"
WINUPDATE +14 +5 111 ' you can winupdate more than
"(508) 365-2359 2400 baud" ' one line at a time
"(508) 368-4137 2400-14.4K USR"
"(508) 368-7036 2400-14.4K V.32"
WAIT +36 +10 ' wait for the enter key

END ' exit the system normally

' ---------------------------------------------------
' Installation Failure. It is a good idea to add a
' similar routine to the bottom of all script files.
' ---------------------------------------------------
:INSTALL_FAILURE
WINOPEN 0 12 79
"THE INSTALLATION PROGRAM FAILED PRIOR TO COMPLETION"
""
"Possible reasons:"
" -- The floppy disk was removed prior to completion."
" -- The floppy disk was damaged during shipping."
" -- Your disk drive is out of alignment."
""
"Press [Enter] to remove incomplete program files."
WAIT 62 20
' delete all partial files using internal variables
' ~1 = the drive the user installed to (C: was the default)
' ~2 = the path the user installed to (\SAMPLE was the default)
DELETE ~1~2\*.* 0 0 31
' now remove the directory
RD ~1~2
WINCLOSE
WINOPEN 0 12 31
"Partially Installed Files are Now Deleted."
""
" Press [Enter] to Quit."
WAIT 47 15


  3 Responses to “Category : Miscellaneous Language Source Code
Archive   : FINISH24.ZIP
Filename : INSTALL.FIL

  1. Very nice! Thank you for this wonderful archive. I wonder why I found it only now. Long live the BBS file archives!

  2. This is so awesome! 😀 I’d be cool if you could download an entire archive of this at once, though.

  3. But one thing that puzzles me is the “mtswslnkmcjklsdlsbdmMICROSOFT” string. There is an article about it here. It is definitely worth a read: http://www.os2museum.com/wp/mtswslnk/