Category : Science and Education
Archive   : HEIGHT.ZIP
Filename : HOWTALL.BAS

10 CLEAR 500
20 DIM M(60)
30 DEFSTR S
40 FOR X=1 TO 48
50 READ M(X)
60 NEXT
70 WIDTH 80 : COLOR 11,1 : CLS
80 PRINT" HOW TALL"
90 PRINT" By Bruce T. Goldman"
100 PRINT
110 PRINT"This ÿprogram predicts the adult height of children from birth to ÿ18."
120 PRINT"At age enter 0 for birth, .25 for 3 months, .5 for 6 months, .75 for 9"
130 PRINT"month. The program can also predict for all ages from 1 to 18, and 1.5"
140 PRINT"and 2.5 for one and a half and two and a half years respectivily." : PRINT
150 PRINT"Prediction ÿmay ÿbe ÿquite inaccurate prior to age 2 due ÿto ÿmaternal"
160 PRINT"effect. ÿÿAfter ÿage ÿ10 ÿthe accuracy is ÿgreatly ÿincreased. ÿÿThe"
170 PRINT"prediction is more correct for females than males and inaccuracy of up"
180 PRINT"to 4% ÿcan be found among 14 year old boys. ÿTherefore, ÿthis program"
190 PRINT"takes an educated guess based on the norms of others." : PRINT
200 PRINT"Reference: Guinness Illustrated Encyclopedia of facts (1981) pg 337" : PRINT
210 PRINT : INPUT"How old is the child";A
220 X=A
230 IF X>18 THEN CLS: INPUT"The child must be younger than 18, press ENTER";X: GOTO 70
240 INPUT"How tall is the child in inches";Z
250 INPUT"Is the child a (b)oy or (g)irl";S
260 IF X=0 THEN X=1
270 IF X=.25 THEN X=2
280 IF X=.5 THEN X=3
290 IF X=.75 THEN X=4
300 IF X=1 THEN X=5
310 IF X=1.5 THEN X=6
320 IF X=2 THEN X=7
330 IF X=2.5 THEN X=8 ELSE X=X+6
340 IF S="F" OR S="f" OR S="g" OR S="G" THEN X=X+24
350 Y=Z*(100/M(X))
360 U=INT(Y/12)
370 WIDTH 40 : CLS : PRINT : PRINT : PRINT : PRINT
380 COLOR 15 : PRINT" HOW TALL PREDICTION" : PRINT : PRINT : PRINT : PRINT : COLOR 11
390 PRINT" At age";: COLOR 12 : PRINT A;: COLOR 11 : PRINT"the child has reached": COLOR 12 : PRINT M(X)"%";: COLOR 11 : PRINT" of height and should grow to"
400 COLOR 10 : PRINT INT(Y);: COLOR 11 : PRINT"inches or";: COLOR 14 : PRINT U;: COLOR 11 : PRINT "feet";: COLOR 14 : PRINT INT(Y-(U*12));: COLOR 11 : PRINT"inches tall."
410 COLOR 15 : PRINT : PRINT : PRINT : PRINT : PRINT" Press ENTER for next person" : PRINT" or Press Q to Quit"
420 SS=INKEY$ : IF SS="" THEN 420
425 IF SS="Q" OR SS="q" THEN WIDTH 80 : CLS : SYSTEM
430 GOTO 70
440 DATA 28.6, 33.9, 37.7, 40.1, 42.2, 45.6, 49.5, 51.6, 53.6, 58, 61.8
450 DATA 65.2, 69, 72, 75, 78, 81.1, 84.2, 87.3, 91.5, 96.1, 98.3, 99.1, 99.8
460 DATA 30.9, 36, 39.8, 42.2, 44.7, 48.8, 52.8, 54.8, 57, 61.8, 66.2, 70.3
470 DATA 74, 77.5, 80.7, 84.4, 88.4, 92.9, 96.5, 98.3, 99.1, 99.6, 100, 100