Category : Science and Education
Archive   : FEMIS.ZIP
Filename : FRAME_BU.DAT

 
Output of file : FRAME_BU.DAT contained in archive : FEMIS.ZIP
* FRAME_BU.DAT Frame Buckling Analyses of 2-D Structure
*
* Elastic Stability Analysis of a 2-D Frame Structure uses the incremental
* stiffness matrix. FEM data is for a 16 element model. Conventional assembly
* assumes horizontal axial beam loads @ nodepoints 5 & 13 as well as vertical
* column loads @ these points. This means that incremental stiffness matrices
* (BB)e will be generated and assembled for each element in the model. It is
* difficult to model load distributions, etc.
*
* Buckling due to column loads can be implemented by assembling only column
* elements and by developing an equivalent spring system for the remaining
* structure. This is the recommended procedure. However, we will proceed
* with less rational approaches.
*
* FEMIS CAPABILITIES FOR FRAMEWORK STABILITY ANALYSIS
*
* .. FEMIS can assemble elements selectively. This means that load can be
* more realistically modelled (scaling partial assemblies).
*
* .. FEMIS is limited to linear elastic analysis, flexural buckling only.
* More complex buckling forms, e.g., coupled twist-flexural buckling, are
* not accommodated.
*
* | Vertical Load | Vertical Load
* V 6 7 8 9 10 11 12 V
* Hor. -> 5 *-----*-----*-----*-----*-----*-----*-----*-----* 13 <- Hor.
* Load | (5) (6) (7) (8) (9) (10) (11) (12) | Load
* | (4) (13) |
* 4 * * 14
* | |
* | (3) (14) |
* 3 * * 15
* | |
* | (2) (15) |
* 2 * Y * 16
* | | |
* | (1) | (16) |
* 1 _x__ |____ X __x_17
* Fixed BC Fixed BC
*
*______________________________________________________________________________
* FRAME MODEL
*______________________________________________________________________________
*
Nodepoint 1 -256. 0. 0.
Nodepoint 2 -256. 48. 0.
Nodepoint 3 -256. 96. 0.
Nodepoint 4 -256. 144. 0.
Nodepoint 5 -256. 192. 0.
Nodepoint 13 256. 192. 0.
Nodepoint 14 256. 144. 0.
Nodepoint 15 256. 96. 0.
Nodepoint 16 256. 48. 0.
Nodepoint 17 256. 0. 0.
Nodepoint 6 -192. 192. 0.
Nodepoint 7 -128. 192. 0.
Nodepoint 8 -64. 192. 0.
Nodepoint 9 0. 192. 0.
Nodepoint 10 64. 192. 0.
Nodepoint 11 128. 192. 0.
Nodepoint 12 192. 192. 0.
Material 1 30000000. .3 .0007333
GeoProperty 1 10.0 100.0
Beam2 1 1 1 1 2
Beam2 2 1 1 2 3
Beam2 3 1 1 3 4
Beam2 4 1 1 4 5
Beam2 5 1 1 5 6
Beam2 6 1 1 6 7
Beam2 7 1 1 7 8
Beam2 8 1 1 8 9
Beam2 9 1 1 9 10
Beam2 10 1 1 10 11
Beam2 11 1 1 11 12
Beam2 12 1 1 12 13
Beam2 13 1 1 13 14
Beam2 14 1 1 14 15
Beam2 15 1 1 15 16
Beam2 16 1 1 16 17
sptc 5 6 x ! With inextensional buckling, it is possible to use a single
sptc 5 7 x ! dof for all horizontal beam dofs.
sptc 5 8 x
sptc 5 9 x ! Removal of duplicate dofs improves numerical conditioning.
sptc 5 10 x
sptc 5 11 x ! Try this problem without "sptc" operations. (Change all
sptc 5 12 x ! "32" dimensional references to "45".)
sptc 5 13 x
sptc 1 4 y ! Inextensional buckling: Use single dof for vertical column
sptc 1 3 y ! dofs.
sptc 1 2 y
sptc 17 14 y ! inextensional buckling, single dof for vertical column dof
sptc 17 15 y
sptc 17 16 y
dBC/x 1 0.0 ! fixed BCs @ column base
dBC/y 1 0.0
rBC/z 1 0.0
dBC/x 17 0.0 ! fixed BCs @ column base
dBC/y 17 0.0
rBC/z 17 0.0
setDOF
FEMprint
define Displ(nFEM,2)
FEMassemble/part BK _ BB _ ! assemble stiffness & incremental stiffness
*
* Reduce Eigenvalue Problem to standard symmetric form. In general, the
* incremental stiffness matrix is ill-conditioned and/or singular.
*
BI = BKaa" ! invert partitioned stiffness matrix
factor BI BU ! factor inverse stiffness to upper triangular form
BU' = BL ! lower triangular factor is transpose of upper factor
BD = - BU * BBaa * BL ! negative sign indicates compression
eigen BD EVEC EVAL
print/e EVAL ! print eigenvalues in exponential form
BL * EVEC = VEC
normalize VEC
rmvsm Displ VEC 1 30 31 31 ! select critical buckling modes
print Displ ! print "raw" displacement data
printDispl Displ ! displacement data expands to include BCs
reciprocal EVAL ! buckling loads are reciprocal of eigenvalues
print EVAL ! lowest buckling load occurs in horizontal beam
reviewoutput
define CrDispl(nFEM,1)
copysm CrDispl Displ 1 2 31 2 ! horizontal beam mode is most critical
* The critical buckling load occurs in the horizontal beam. Observe the
** symmetric mode shape in the beam.
plot CrDispl
copysm CrDispl Displ 1 1 31 1
** The next critical buckling load.
plot CrDispl
*______________________________________________________________________________
* Same model with partial assembly of column elements only.
*______________________________________________________________________________
*
* partial assembly of elements associated with columns
zero BB
FEMassemble/part _ _ BB _ @ 1 2 3 4 13 14 15 16
BD = - BU * BBaa * BL
eigen BD EVEC EVAL
BL * EVEC = VEC
normalize VEC
reciprocal EVAL ! buckling loads are reciprocal of eigenvalues
print EVAL
copysm Displ VEC 1 30 31 31 ! select critical buckling loads
printDispl Displ
copysm CrDispl VEC 1 31 31 31 ! column mode is now most critical
printDispl CrDispl
plot CrDispl
reviewoutput
mode
*______________________________________________________________________________
* HORIZONTAL BEAM MODEL
*______________________________________________________________________________
*
resetFEMIS
Nodepoint 5 -256. 0. 0.
Nodepoint 6 -192. 0. 0.
Nodepoint 7 -128. 0. 0.
Nodepoint 8 -64. 0. 0.
Nodepoint 9 0. 0. 0.
Nodepoint 10 64. 0. 0.
Nodepoint 11 128. 0. 0.
Nodepoint 12 192. 0. 0.
Nodepoint 13 256. 0. 0.
Material 1 30000000.0
GeoProperty 1 10.0 100.0
Beam2 5 1 1 5 6
Beam2 6 1 1 6 7
Beam2 7 1 1 7 8
Beam2 8 1 1 8 9
Beam2 9 1 1 9 10
Beam2 10 1 1 10 11
Beam2 11 1 1 11 12
Beam2 12 1 1 12 13
sptc 5 6 x ! With inextensional buckling, it is possible to use a single
sptc 5 7 x ! dof for all horizontal beam dofs.
sptc 5 8 x
sptc 5 9 x ! Removal of duplicate dofs improves numerical conditioning.
sptc 5 10 x
sptc 5 11 x ! Try this problem without "sptc" operations. (Change all
sptc 5 12 x ! "32" dimensional references to "45".)
sptc 5 13 x
dBC/x 5 0.0 ! simply supported BC for horizontal beam.
dBC/y 5 0.0
dBC/y 13 0.0
setDOF
FEMprint
define Displ(nFEM,1)
FEMassemble/part BK _ BB _ ! assemble stiffness & incremental stiffness
BI = BKaa"
factor BI BU
BU' = BL
BD = - BU * BBaa * BL ! negative sign indicates compression
eigen BD EVEC EVAL
BL * EVEC = VEC
normalize VEC
rmvsm Displ VEC 1 [nFEM] ! select critical buckling mode
printDispl Displ
reciprocal EVAL ! buckling loads are reciprocal of eigenvalues
print EVAL
reviewoutput
plot Displ
*______________________________________________________________________________
* VERTICAL COLUMN MODEL
*______________________________________________________________________________
*
resetFEMIS
Nodepoint 1 0. 0. 0.
Nodepoint 2 0. 48. 0.
Nodepoint 3 0. 96. 0.
Nodepoint 4 0. 144. 0.
Nodepoint 5 0. 192. 0.
Material 1 30000000.
GeoProperty 1 10.0 100.0
Beam2 1 1 1 1 2
Beam2 2 1 1 2 3
Beam2 3 1 1 3 4
Beam2 4 1 1 4 5
sptc 1 5 y ! Inextensional buckling: Use single dof for vertical column
sptc 1 4 y ! dofs.
sptc 1 3 y
sptc 1 2 y
dBC/x 1 0.0 ! fixed BCs @ column base
dBC/y 1 0.0
rBC/z 1 0.0
setDOF
FEMprint
define Displ(nFEM,1)
FEMassemble/part BK _ BB _ ! assemble stiffness & incremental stiffness
BI = BKaa"
factor BI BU
BU' = BL
BD = - BU * BBaa * BL ! negative sign indicates compression
eigen BD EVEC EVAL
BL * EVEC = VEC
normalize VEC
rmvsm Displ VEC 1 [nFEM] ! select critical buckling mode
printDispl Displ
reciprocal EVAL ! buckling loads are reciprocal of eigenvalues
print EVAL
reviewoutput
plot Displ
stop


  3 Responses to “Category : Science and Education
Archive   : FEMIS.ZIP
Filename : FRAME_BU.DAT

  1. Very nice! Thank you for this wonderful archive. I wonder why I found it only now. Long live the BBS file archives!

  2. This is so awesome! 😀 I’d be cool if you could download an entire archive of this at once, though.

  3. But one thing that puzzles me is the “mtswslnkmcjklsdlsbdmMICROSOFT” string. There is an article about it here. It is definitely worth a read: http://www.os2museum.com/wp/mtswslnk/