Category : Science and Education
Archive   : ASCIIRF2.ZIP
Filename : ABLOAD.PRG

******************************************************************************
* ABLOAD.PRG *
* Program to load citations and abstracts into dBASE IV *
* *
* Peter M. LePoer 1989 *
******************************************************************************

*
* first clear screen, initialize variables, set parameters
*

clear
dbasename = space(30)
filename = space(30)
abfield = space(10)
abname = space(10)
abstract = " "
temp = " "
complete = .F.
set escape on
set carry off

*
* define window for messages
*

define window status from 13,25 to 21,55

*
* print header
*

@ 1,31 say "IMPORT ASCII FILES"
@ 2,0 TO 2,79

*
* prompt for needed information
*

do while .not. complete

complete = .T.

@ 5, 15 SAY "DATABASE: "
@ 5, 37 GET dbasename
@ 7, 15 SAY "CITATION FILE: "
@ 7, 37 GET filename
@ 9, 15 say "ABSTRACT FIELD: "
@ 9, 37 GET abfield
@ 11,15 say "ABSTRACT NAME FIELD: "
@ 11, 37 GET abname

@ 24,0 to 24,79
read

*
* make sure everything necessary was entered
*

if left(dbasename, 1) = " " .or. left(filename, 1) = " " .or. left(abfield, 1) = " " .or. left(abname, 1) = " "
complete = .F.
activate window status
@ 2,1 say "All fields Required"
@ 4,1 say "Continue (Y/N) " get temp picture "!"
read
if temp = "N"
close all
deactivate window status
return
else
complete = .F.
deactivate window status
endif
temp = " "
endif

enddo

*
* display window with message
*

activate window status

@ 3,1 say "Appending Records..."

*
* append records to file
* to correctly add the abstracts, first determine record number of first
* record to be added, store the number in the "firstrec" variable,
* and then start there with the addition of abstracts
*

use &dbasename

go bottom

if reccount() > 0
firstrec = recno() + 1
else
firstrec = 1
endif

*
* append records
*

append from &filename type delimited

*
* routine to add abstracts uses the "append memo" command in dBASE IV
* it finds the name of the abstract file in the abstract name field of
* the appended records
*

go firstrec

@ 3,1 clear to 4, 25
@ 3,1 say "Adding Abstracts..."

do while .not. eof()
if &abname <> " "
abstract = &abname
append memo &abfield from &abstract
abstract = " "
endif
skip
enddo

@ 3,1 clear to 4, 25
@ 2,2 say "Processing Complete"
@ 3,1 say " "
wait

*
* finished - deactivate window, close database, clear screen, and return to dBASE
*

deactivate window status
clear
close all
return