Category : Dbase (Clipper, FoxBase, etc) Languages Source Code
Archive   : TMKPDB3.ZIP
Filename : CVS.PRG

CLEAR
SET TALK OFF
?"ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿"
?"³ TIME KEEPER * END OF MONTH * ³"
?"³ COMPTIME, VACATION, SICKLEAVE REPORT ³"
?"³ ver. 1.1 7/31/85 ³"
?"ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ"
IF FILE("DUMMY.$$$") THEN
?"***** WARNING! THIS PROGRAM HAS ALREADY BEEN RUN THIS MONTH!"
ENDIF
WAIT "DO YOU WISH TO UPDATE THE OLD CARRYOVER VALUES? (Y/N) " TO RPLC
IF UPPER(RPLC) = "Y" THEN
SET ALTERNATE TO DUMMY
SET ALTERNATE ON
?"O.K."
CLOSE ALTERNATE
?" ***** NOTE THAT UNALTERABLE CHANGES TO FILES WILL TAKE PLACE WHEN THIS"
?"PROGRAM IS RUN. BE SURE YOU HAVE PERMISSION FROM THE SYSTEM MONITOR!"
ENDIF
WAIT "PRESS [C] TO CONTINUE, ANY OTHER KEY TO ABORT." TO CNT
IF UPPER(CNT) <> "C" THEN
RETURN
ENDIF
?"PREPARE YOUR PRINTER"
?" REQUIRES 165 + COLUMNS. 13inch, 17 cpi settings recommended."
?" Type an ASCII code or hit [Return]."
CD = 1
C = ""
DO WHILE CD <> 32
CD = 32
INPUT "CODE (1-255):" TO CD
IF CD > 0 THEN
C = C + CHR(CD)
ENDIF
ENDDO
SET PRINT ON
? C
SET PRINT OFF
EJECT
FRC = 1
SELECT 1
USE EMPLOYEE
SET INDEX TO NAME
SET FILTER TO BENEFITS = "Y" .OR. BENEFITS = "B"
SELECT 2
USE TIMESHEE ALIAS TM
SET INDEX TO TIMEDEX
SELECT 1
GO TOP
SET DEVICE TO PRINT
SET PROCEDURE TO CVSPRO
?" PRINTING HEADER..."
@ 1,75 SAY "TJKM CVS REPORT"
@ 2,79 SAY DTOC(DATE())
DO HEADER
GO TOP
DO WHILE .NOT. EOF()
STORE BENEFITS TO BENEFIT
STORE NAME TO NM
STORE DEPARTMENT TO DPT
STORE NUMBER TO NUM
STORE STARTDATE TO DT
STRT = DTOC(DT)
EMPL = ROUND((DATE() - DT) / 365,2)
STORE COMPCARRY TO CMPC
STORE VACCARRY TO VACC
STORE SICKCARRY TO SICC

SELECT 2
LOCATE FOR EMPNUM = NUM .AND. TASK = "VACATION"
IF BENEFIT = "B" THEN
?NM + " IS REGISTERED AS A PART/FULL TIME EMPLOYEE."
INPUT "WHAT IS THE RAW FRACTION OF EARNINGS TO BE POSTED " TO FRC
IF FRC > 1 THEN
FRC = FRC / 100
ENDIF
ELSE
FRC = 1
ENDIF
STORE MNTHRS TO VACU
DO CASE
CASE EMPL <= 5
VACE = 6.7
ANN = 80
CASE EMPL > 5 .AND. EMPL <= 10
VACE = 10.0
ANN = 120
CASE EMPL > 10
VACE = 13.3
ANN = 160
ENDCASE
VACE = VACE * FRC
VACN = VACC + VACE - VACU
IF VACN > 2*ANN THEN
VACN = 2 * ANN
ENDIF
LOCATE FOR EMPNUM = NUM .AND. TASK = "SICKLEAV"
STORE MNTHRS TO SICU
DO CASE
CASE EMPL <= 3
SICE = 6.7
ANN = 80
CASE EMPL > 3
SICE = 8.0
ANN = 96
ENDCASE
SICE = SICE * FRC
SICN = SICC + SICE - SICU
IF EMPL <= 10 .AND. SICN > 4 * ANN THEN
SICN = 4 * ANN
ENDIF
IF EMPL > 11 .AND. SICN > 480 THEN
SICN = 480
ENDIF
LOCATE FOR EMPNUM = NUM .AND. TASK = "COMPACC"
STORE MNTHRS TO CMPA
CMPA = CMPA * FRC
LOCATE FOR EMPNUM = NUM .AND. TASK = "COMPUSED"
STORE MNTHRS TO CMPU
IF SUBSTR(DPT,1,2) = "EN" THEN
CMPA = CMPA - 10
IF CMPA < 0 THEN
CMPA = 0
ENDIF
ENDIF
?NM + "HAS ACCRUED: " + STR(CMPA,5,2) + " HOURS THIS MONTH."
?" IF THIS IS TO BE CHANGED, ENTER NEW VALUE. OTHERWISE HIT [Return]."
INPUT "ACCRUAL:" TO CMPA
CMPN = CMPC + CMPA - CMPU
IF CMPN > 40 THEN
CMPN = 40
ENDIF
DO LIST
IF UPPER(RPLC) = "Y" THEN
?"UPDATING CARRYOVER VALUES."
REPLACE COMPCARRY WITH CMPN
REPLACE VACCARRY WITH VACN
REPLACE SICKCARRY WITH SICN
ENDIF
SELECT 1
SKIP 1
ENDDO
?"RUN COMPLETED."
SET DEVICE TO SCREEN
RETURN