Category : BASIC Source Code
Archive   : QB_CODE.ZIP
Filename : WINDOW.BAS

'
' WINDOW.BAS - For the QuickBASIC Toolbox
' Dynamic Window Routines
'

'
' $INCLUDE: 'TOOLBOX.BI'
'

DEFINT A-Z

FUNCTION CLOSEWINDOW$ (WINDOW$)
ROW1 = ASC(MID$(WINDOW$, LEN(WINDOW$) - 3, 1))
COL1 = ASC(MID$(WINDOW$, LEN(WINDOW$) - 2, 1))
ROW2 = ASC(MID$(WINDOW$, LEN(WINDOW$) - 1, 1))
COL2 = ASC(MID$(WINDOW$, LEN(WINDOW$), 1))
RESTORESCREEN ROW1, COL1, ROW2, COL2, SADD(WINDOW$)
CLOSEWINDOW$ = ""
END FUNCTION

SUB DRAWWINDOW (ROW1, COL1, ROW2, COL2, WATT, BFLG, BATT)
FILLSCREEN ROW1, COL1, ROW2, COL2, 32, WATT
IF BFLG <> NOBORDER THEN
DRAWBOX ROW1, COL1, ROW2, COL2, BFLG, BATT
END IF
END SUB

SUB HORIZONTALBAR (WINDOW$, CURRENT, TOTAL, ATT)
ROW1 = ASC(MID$(WINDOW$, LEN(WINDOW$) - 3, 1))
COL1 = ASC(MID$(WINDOW$, LEN(WINDOW$) - 2, 1))
ROW2 = ASC(MID$(WINDOW$, LEN(WINDOW$) - 1, 1))
COL2 = ASC(MID$(WINDOW$, LEN(WINDOW$), 1))
IF TOTAL = 0 THEN
CURRENT = 0
TOTAL = 1
END IF
FILLONE ROW2, COL1 + 1, 27, ATT
FILLSCREEN ROW2, COL1 + 2, ROW2, COL2 - 2, 177, ATT
FILLONE ROW2, COL2 - 1, 26, ATT
MARKER& = (COL2 - COL1 - 4) * CURRENT / TOTAL + COL1 + 2
FILLONE ROW2, MARKER&, 176, ATT
END SUB

FUNCTION OPENWINDOW$ (ROW1, COL1, ROW2, COL2, WATT, BFLG, BATT)
A$ = SPACE$((COL2 - COL1 + 1) * 2 * (ROW2 - ROW1 + 1) + 4)
MID$(A$, LEN(A$) - 3, 1) = CHR$(ROW1)
MID$(A$, LEN(A$) - 2, 1) = CHR$(COL1)
MID$(A$, LEN(A$) - 1, 1) = CHR$(ROW2)
MID$(A$, LEN(A$), 1) = CHR$(COL2)
SAVESCREEN ROW1, COL1, ROW2, COL2, SADD(A$)
IF WATT THEN
DRAWWINDOW ROW1, COL1, ROW2, COL2, WATT, BFLG, BATT
END IF
OPENWINDOW$ = A$
END FUNCTION

SUB SCROLLWINDOW (ROW1, COL1, ROW2, COL2, NUM, DFLG, ATT)
COLS = (COL2 - COL1 + 1) * 2
ROWS = ROW2 - ROW1 + 1
A$ = SPACE$(COLS * ROWS)
SAVESCREEN ROW1, COL1, ROW2, COL2, SADD(A$)
SELECT CASE DFLG
CASE UP
FOR I = ROW1 + NUM TO ROW2
MID$(A$, (I - NUM - ROW1) * COLS + 1, COLS) = MID$(A$, (I - ROW1) * COLS + 1, COLS)
NEXT I
CASE DOWN
FOR I = ROW2 TO ROW1 + NUM STEP -1
MID$(A$, (I - ROW1) * COLS + 1, COLS) = MID$(A$, (I - NUM - ROW1) * COLS + 1, COLS)
NEXT I
CASE LEFT
FOR I = ROW1 TO ROW2
MID$(A$, (I - ROW1) * COLS + 1, COLS - NUM * 2) = MID$(A$, (I - ROW1) * COLS + 1 + NUM * 2, COLS - NUM * 2)
NEXT I
CASE ELSE
FOR I = ROW1 TO ROW2
MID$(A$, (I - ROW1) * COLS + 1 + NUM * 2, COLS - NUM * 2) = MID$(A$, (I - ROW1) * COLS + 1, COLS - NUM * 2)
NEXT I
END SELECT
RESTORESCREEN ROW1, COL1, ROW2, COL2, SADD(A$)
IF ATT THEN
SELECT CASE DFLG
CASE UP
FILLSCREEN ROW2 - NUM + 1, COL1, ROW2, COL2, 32, ATT
CASE DOWN
FILLSCREEN ROW1, COL1, ROW1 + NUM - 1, COL2, 32, ATT
CASE LEFT
FILLSCREEN ROW1, COL2 - NUM + 1, ROW2, COL2, 32, ATT
CASE ELSE
FILLSCREEN ROW1, COL1, ROW2, COL1 + NUM - 1, 32, ATT
END SELECT
END IF
END SUB

SUB VERTICALBAR (WINDOW$, CURRENT, TOTAL, ATT)
ROW1 = ASC(MID$(WINDOW$, LEN(WINDOW$) - 3, 1))
COL1 = ASC(MID$(WINDOW$, LEN(WINDOW$) - 2, 1))
ROW2 = ASC(MID$(WINDOW$, LEN(WINDOW$) - 1, 1))
COL2 = ASC(MID$(WINDOW$, LEN(WINDOW$), 1))
IF TOTAL = 0 THEN
CURRENT = 0
TOTAL = 1
END IF
FILLONE ROW1 + 1, COL2, 24, ATT
FILLSCREEN ROW1 + 2, COL2, ROW2 - 2, COL2, 177, ATT
FILLONE ROW2 - 1, COL2, 25, ATT
MARKER& = (ROW2 - ROW1 - 4) * CURRENT / TOTAL + ROW1 + 2
FILLONE MARKER&, COL2, 176, ATT
END SUB