Category : Assembly Language Source Code
Archive   : VGAKIT60.ZIP
Filename : SVGA640.ASM

include model.inc
include vesa.inc

;
; VGAKIT Version 6.0
;
; Copyright 1988,89,90,91,92,93,94 John Bridges
; Free for use in commercial, shareware or freeware applications
;
; SVGA640.ASM
;
;
.data
extrn cirrus:byte,everex:byte,paradise:byte,tseng:byte,trident:byte
extrn t8900:byte,ativga:byte,aheada:byte,aheadb:byte
extrn oaktech:byte,video7:byte,chipstech:byte,tseng4:byte,genoa:byte
extrn ncr:byte,compaq:byte,acumos:byte,vesa:byte

extrn maxx:word,maxy:word,scanline:word,ourseg:word

.code
public svga640
extrn mkadrtbl:proc,txtmode:proc,setmany:proc,vesaset:proc

svga640 proc ;Set 640x480x256 on most SVGA cards
mov [ourseg],0a000h
mov ax,640
mov [maxx],ax ;default width to 640 for now
mov [scanline],ax

cmp [vesa],0
jz novs
mov bx,101h
call vesaset
jmp godo2
novs: cmp [compaq],0
jz nocp
mov [scanline],1024
mov ax,2eh
jmp godo
nocp: cmp [genoa],0
jz nogn
mov ax,5ch
jmp godo
nogn: cmp [ncr],0
jz noncr
mov ax,5fh
jmp godo
noncr: cmp [oaktech],0
jz noak
mov ax,53h
jmp short godo
noak: cmp [aheada],0
jnz skp
cmp [aheadb],0
jz noab
skp: mov ax,61h
jmp short godo
noab: cmp [everex],0
jz noev
mov ax,70h
mov bl,30h
jmp short godo
noev: cmp [ativga],0
jz noati
mov ax,62h
jmp short godo
noati: cmp [trident],0
jz notr
mov ax,5dh
jmp short godo
notr: cmp [video7],0
jz nov7
mov ax,6f05h
mov bl,67h
jmp short godo
nov7: cmp [chipstech],0
jz noct
mov ax,79h
jmp short godo
noct: cmp [acumos],0
jnz dopd
cmp [paradise],0
jz nopd
dopd: mov ax,5fh
jmp short godo
nopd: cmp [tseng],0
jz nots
mov ax,2eh
godo: int 10h

godo2: mov ax,40h
mov es,ax
mov al,es:[84h] ;get height of screen
inc al
mul byte ptr es:[85h]
mov [maxy],ax
call mkadrtbl
nots: ret
svga640 endp

end